Hello World
Spiga

五十种语言的“圣诞快乐”(下):F#实现

2009-12-28 11:18 by 老赵, 6917 visits

不知道大家的圣诞节过的如何?有没有玩点啥有趣的东西?上次的文章中我们主要分析了使用Google Translate进行文字翻译的方式,并使用C#写了一个简单的的翻译程序,效果良好。不过,在平时开发过程中,对于此类问题我常用F#来解决这样的问题。那么使用F#来实现此类任务有什么优势吗?不错,我们现在便来看看这个问题。

简单的F#实现

话说F#和.NET框架可以无缝集成,因此理论上之前我们的C#代码怎么写,便可以使用F#来照着抄一遍。例如,我们先定义一个Sync模块,其中先定义一个获取全部目标语言的getLanguages函数:

#light

module Sync

open System
open System.Text.RegularExpressions
open System.Net
open System.Web
open System.Web.Script.Serialization
open System.Collections.Generic
open System.Text

type private LangMap = Dictionary<string, string>

let private getLanguages() = 
    let url =
        "http://translate.googleapis.com" +
        "/translate_a/l?client=te&hl=zh-CN&cb=_callbacks_._0g3mb650r"
    
    let webClient = new WebClient()
    let script = webClient.DownloadString(url)

    let json = Regex.Match(script, @"'tl':({.+})}\)").Groups.Item(1).Value
    let serializer = new JavaScriptSerializer()
    serializer.Deserialize<LangMap>(json)

这个函数与之前C#版本的GetLanguages方法可谓一模一样,其返回结果便是一个字典,存储了目标语言的代号和名称——当然,这边我为Dictionary<string, string>取了一个别名LangMap,这样使用起来感觉更为方便,语义也更加清晰。

同样的,我们“翻译”一遍之前的Translate方法,变成如今的translateText函数:

let private translateText (text:string) sl tl =
    let url = 
        "https://translate.googleapis.com" +
        "/translate_a/t?client=te&format=html&v=1.0"

    let encoded = text |> HttpUtility.UrlEncode
    let data = sprintf "q=%s&sl=%s&tl=%s&tc=1" encoded sl tl

    let webClient = new WebClient()
    webClient.Encoding <- Encoding.UTF8
    let userAgent = "Mozilla/4.0 (compatible; MSIE 8.0; Windows NT 6.0; Trident/4.0;)"
    webClient.Headers.Add(HttpRequestHeader.UserAgent, userAgent)

    let json = webClient.UploadString(url, data)
    let serializer = new JavaScriptSerializer()
    serializer.Deserialize<string>(json)

而最终进行多种语言翻译的,则是使用公有的translate函数:

let translate text sl = 
    let languages = getLanguages()

    let translated =
        languages
        |> Seq.map (fun p -> translateText text sl p.Key)

    let names = languages  |> Seq.map (fun p -> p.Value)
    Seq.zip names translated |> Seq.toArray

首先,所有语言会存入一个叫做languages的容器中,它是一个字典,实现了IEnumerable<KeyValuePair<string, string>>,在F#中便是seq<KeyValuePair<string, string>>,因此我们使用Seq模块的map方法将其转化为翻译后的结果,并存放在translated中。然后,我们获得每种语言的名称,最终与翻译的结果zip即可。translate函数最终返回的是一个存放着元组的数组,元组的类型是string * string。

至于调用,自然是很容易的。F#控制台程序也需要定义main函数,如下:

[<EntryPoint>]
let main args =

    let output = 
        Sync.translate "圣诞快乐" "zh-CN"
        |> Array.map (fun (lang, text) -> sprintf "%s:o%s" lang text)

    File.WriteAllLines("output.txt", output)
    
    Console.ReadLine() |> ignore
    0

当然,如果我们只是把F#用成这样,那实在就没有多大价值了。

异步编程

刚才的代码放在名为Sync的模块中,很明显这是“同步”的。对于此类IO操作,使用同步IO是一件非常不明智的事情。当然,对于目前这样的小程序来说,使用同步IO并没有什么问题。但是您一会儿也会发现,异步IO对目前的情形也是十分有价值的。

异步IO除了“不阻塞”的含义在里面之外,我认为还需要包括“事件触发”这个含义在里面。例如,JDK很早就支持了异步IO,但是直到目前为止(JDK 6),它在Windows平台上的相关实现,依旧只是简单的“非阻塞”,而非基于Windows的异步IO机制IOCP。于此相对,它在Linux平台上的实现却使用了高效的epoll。因此,如MinaJetty等高性能IO通信框架在Windows下的表现要比Linux差很多——您会经常看到时不时有人以此来证明Windows性能低下,但我倒认为这只能证明Java的跨平台只是“功能”而不是“性能”,意义大打折扣。

至于跨平台的IO类库并非没有,例如著名的libevent便是一例。不过在JDK 7中“据说”会修复这方面问题,拭目以待。

对于在Windows平台下真正的异步IO机制IOCP,我之前在多篇文章中有所提及(包括与其有关的IO线程池)。在.NET平台上,各种类库的异步通信方式自然使用了IOCP,自不必提。但是,异步编程的性能虽然好,但它的最大问题还是“方便性”,最基础的一点,由于任务流需要分两部分进行,那么我们自然需要保留上下文吧?即便是如C#中提供了匿名函数,可以自动生成闭包来保持上下文,但是还是有其他问题——例如,异常处理怎么办?

当然,利用C#中的yield关键字可以简化这些问题,但是F#给我们更好的解决方案。F#应对异步编程提供了一个名为“异步工作流”的结构,它基于F#的“工作流”特性开发了一套异步类库,关于这一点在上次的Comet原型中也有提及。异步工作流的优势在于把一个“二段式”的异步调用合并在一起,这样在调用的时候便可以同步操作的方式进行。如此,无论是逻辑中的上下文信息还是异常处理都变得异常简单。

对于异步操作的“合并”,例如可以根据最常见的APM模式(即Begin/End)生成“单步”的工作流。不过对于WebClient来说,它的异步操作并非APM形式,而是基于“事件”。不过F#对此也提供了支持,因此我们可以为WebClient扩展两个函数:

type WebClient with
    member c.GetStringAsync(url) = 
        async {
            c.DownloadStringAsync(new Uri(url))
            let! args = c.DownloadStringCompleted |> Async.AwaitEvent
            return args.Result
        }

    member c.PostStringAsync(url, data) = 
        async {
            c.UploadStringAsync(new Uri(url), data)
            let! args = c.UploadStringCompleted |> Async.AwaitEvent
            return args.Result
        }

我们在F#中可以“打开”任意一个类型,为其添加新的成员——不过自然这只是如C#中扩展方法那样的语法糖而已。我们为WebClient添加了GetStringAsync与PostStringAsync两个方法,它们返回的都是结果为一个字符串的异步数据流(即Async<string>),执行这个异步数据流之后便可以得到最终的结果。值得注意的是,async块只是在构造一个逻辑块,并没有真正调用。

于是,我们的getLanguages函数也可进行改写:

let private getLanguages() = 
    async {
        let url =
            "http://translate.googleapis.com" +
            "/translate_a/l?client=te&hl=zh-CN&cb=_callbacks_._0g3mb650r"
        
        let webClient = new WebClient()
        // let script = webClient.DownloadString(url)
        let! script = webClient.GetStringAsync(url)

        let json = Regex.Match(script, @"'tl':({.+})}\)").Groups.Item(1).Value
        let serializer = new JavaScriptSerializer()
        // serializer.Deserialize<LangMap>(json)
        return serializer.Deserialize<LangMap>(json)
    }

您是否发现这段代码与之前的变化?没错,两者几乎一模一样。除了它变成了async构造块之外,唯一的区别只是被注释的两行代码。第一行代码中,原本我们使用的是同步的DownloadString函数,而现在我们则通过执行一个异步数据流(使用let!)来得到结果script——当然,执行的形式却是同步的。除此之外,最后返回结果需要使用return来标明。let!和return(以及其他的如return!)等操作符,都是F#编译器对“工作流”构造块(如async)使用中的“强制措施”,以此避免开发人员的误操作。

同样,translateText函数也将构造一个异步工作流:

let private translateText (text:string) sl tl =
    async {
        let url = 
            "https://translate.googleapis.com" +
            "/translate_a/t?client=te&format=html&v=1.0"

        let encoded = text |> HttpUtility.UrlEncode
        let data = sprintf "q=%s&sl=%s&tl=%s&tc=1" encoded sl tl

        let webClient = new WebClient()
        webClient.Encoding <- Encoding.UTF8
        let userAgent = "Mozilla/4.0 (compatible; MSIE 8.0; Windows NT 6.0; Trident/4.0;)"
        webClient.Headers.Add(HttpRequestHeader.UserAgent, userAgent)

        let! json = webClient.PostStringAsync(url, data) // changed
        let serializer = new JavaScriptSerializer()
        return serializer.Deserialize<string>(json) // changed
    }

使用异步工作流的另一个好处在于,我们可以轻易地将异步工作流并行地执行。例如在目前的场景中,我们可以同时发起50多个异步IO请求,但同时却不占用任何线程——它们可能都在等着IO设备(即网卡)发送设备信号呢。于是乎,我们的translate函数便可以这样写:

let translate text sl = 
    async {
        let! languages = getLanguages()
        let! translated =
            languages
            |> Seq.map (fun p -> translateText text sl p.Key)
            |> Async.Parallel

        let names = languages |> Seq.map (fun p -> p.Value)
        return Seq.zip names translated |> Seq.toArray
    }

并这样调用:

let output = 
    Parallel.translate "圣诞快乐" "zh-CN"
    |> Async.RunSynchronously
    |> Array.map (fun (lang, text) -> sprintf "%s:%s" lang text)

这句代码中的Parallel便是指我们刚才开发的模块。这段代码的执行速度会比Sync模块要快很多,因此此时50多个翻译的请求并不是依次发出,而是同时发出,并通过响应IO设备的事件来工作。不阻塞,高效。

异步工作流的同步执行

之前的代码中,我们是将languages集合转化为一组translateText所生成的异步任务,然后由Async.Parallel合并成一个并行的异步任务。这种调用方式很简单,反而是如果您要将这组异步任务按照顺序一一执行起来比较麻烦。当然,这只是麻烦,并不困难,而且其实同样是非常自然的:

let translateSeq text sl = 
    let rec translateSeq' targets acc =
        async {
            match targets with
            | [] -> return acc |> List.rev
            | t :: ts -> 
                let! result = translateText text sl t
                return! translateSeq' ts (t :: acc)
        }

    async {
        let! languages = getLanguages()
        let targets = languages |> Seq.map (fun p -> p.Key) |> Seq.toList

        let! translated = translateSeq' targets List.empty
        let names = languages |> Seq.map (fun p -> p.Value)
        return Seq.zip names translated |> Seq.toArray
    }

您能解释一下这段代码的写法吗?

最后还是来看看执行效果吧。圣诞已过,新年将至。那么在这里就来祝各位兄弟们新年快乐吧!

所有代码

相关文章

Creative Commons License

本文基于署名 2.5 中国大陆许可协议发布,欢迎转载,演绎或用于商业目的,但是必须保留本文的署名赵劼(包含链接),具体操作方式可参考此处。如您有任何疑问或者授权方面的协商,请给我留言

Add your comment

21 条回复

  1. 吉日嘎拉>不仅权限设计
    *.*.*.*
    链接

    吉日嘎拉>不仅权限设计 2009-12-28 11:19:00

    F#? 能干啥用? 能做web应用程序吗?

  2. Yankee
    *.*.*.*
    链接

    Yankee 2009-12-28 11:20:00

    这就是传说中的沙发?

  3. 随碟附送的
    *.*.*.*
    链接

    随碟附送的 2009-12-28 11:21:00

    不知道F#语言相对C#语言的性能表现如何啊?

  4. 随碟附送的
    *.*.*.*
    链接

    随碟附送的 2009-12-28 11:22:00

    @Yankee
    你坐的是板凳,而且是三楼的地板。

  5. Yankee
    *.*.*.*
    链接

    Yankee 2009-12-28 11:23:00

    @随碟附送的
    只能说吉日太快了....

  6. 风乱发
    *.*.*.*
    链接

    风乱发 2009-12-28 11:25:00

    站个前排也不错~~

  7. 老赵
    admin
    链接

    老赵 2009-12-28 11:25:00

    吉日嘎拉>不仅权限设计:F#? 能干啥用? 能做web应用程序吗?


    F#就是编译成.NET程序集,自然可以开发Web应用程序。

  8. 老赵
    admin
    链接

    老赵 2009-12-28 11:26:00

    随碟附送的:不知道F#语言相对C#语言的性能表现如何啊?


    F#也是编译为IL的,性能方面应该问题不大。

  9. 灵感之源
    *.*.*.*
    链接

    灵感之源 2009-12-28 12:00:00

    let,只让我想起 GWBASIC

  10. winter-cn
    *.*.*.*
    链接

    winter-cn 2009-12-28 12:14:00

    FP在并行计算方面优势明显啊 呵呵

  11. Magic R
    *.*.*.*
    链接

    Magic R 2009-12-28 12:24:00

    我一直以为相比C#,VB的语法是很丑的
    这个更厉害...

  12. 老赵
    admin
    链接

    老赵 2009-12-28 12:42:00

    @Magic R
    觉得F#语法丑呀?你觉得LISP或Haskell如何亚?

  13. 小城故事
    *.*.*.*
    链接

    小城故事 2009-12-28 13:08:00

    @Magic R
    我以前还觉得C系列语法难看得不想碰,觉得VB的语法太舒服了。现在用习惯了C#,觉得也还可以吧,就像谈恋爱,第一眼看外表,第二眼以后看心灵。

    F#现在看着也别扭,多用用就顺眼了吧。

  14. 灵感之源
    *.*.*.*
    链接

    灵感之源 2009-12-28 13:22:00

    @Magic R
    BASIC语法很优美

  15. Ivony...
    *.*.*.*
    链接

    Ivony... 2009-12-28 13:41:00

    F#现在的编译器还有很大的改善空间啊,我尝试编译过几个老赵的F#代码,发现编译器生成了很多不必要的方法(没必要独立成方法的代码),似乎不如C#的干净,在性能上应该会有微弱的反映。

  16. ITniao
    *.*.*.*
    链接

    ITniao 2009-12-28 17:32:00

    光望中..

  17. 晴天猪
    *.*.*.*
    链接

    晴天猪 2009-12-28 23:31:00

    说实话,我真得很讨厌类C语言的;和{}

  18. 老赵
    admin
    链接

    老赵 2009-12-28 23:51:00

    @晴天猪
    你喜欢哪个语言亚?

  19. Jimixu
    *.*.*.*
    链接

    Jimixu 2009-12-29 10:23:00

    他必然喜欢VB

  20. FJ. Zhou
    *.*.*.*
    链接

    FJ. Zhou 2009-12-29 16:51:00

    发现老赵在使用Git管理代码

  21. 晴天猪
    *.*.*.*
    链接

    晴天猪 2010-01-16 23:39:00

    @Jeffrey Zhao
    20楼说对了,就是很喜欢VB,就像写诗一样.

    不喜欢Pascal中的:=, 不喜欢PHP中的$.

发表回复

登录 / 登录并记住我 ,登陆后便可删除或修改已发表的评论 (请注意保留评论内容)

昵称:(必填)

邮箱:(必填,仅用于Gavatar

主页:(可选)

评论内容(大于5个字符):

  1. Your Name yyyy-MM-dd HH:mm:ss

使用Live Messenger联系我